اكسبيرت للتعلم (1)

[التائب اليك]

ان شاء الله حيكون هذا الموضوع موضوع تعليمى لكى يستفيد المبرمجين المبتدئين (امثالى ) وخصوصا لمن ليس لديه خلفيه برمجيه
وان شاء الله اخونا وجدى حيساعدنا فى هذا الموضوع وحيتابعه باستمرار

نبدا
بسم الله الرحمن الرحيم

استراتيجيه اخونا محمد معمو (وهى استراتيجيه رقميه بسيطه)
على المجنون بيفتح بيع تحت الافتتاح ب120 نقطه
وشراء فوق الافتتاح ب 120 نقطه
بهدف 100 واستوب 100
تم تجريب الاستراتيجية من تاريخ 19-3-2008 وحتى 19-3-2009 وكان عدد الصفقات

الناجحة 117 صفقة ,, وعدد الصفقات الخاسرة 31 صفقة ,,
على كلام الاخ معمو

المشكله
انى جيت اعمله باك تست مشتغلش حيث ظهر الاسم بلون فضى
حاجه تانيه
هذا الاكسبيرت وحسب الاستراتيجيه بيلغى الاوامر المعلقه التى لم تتفعل اخر اليوم
وبالتالى ممكن تتفعل صفقات البيع والشراء فى ايام التذبذب وبالتالى ممكن يضرب استوب لوس الاثنين

المطلوب
هو شرط الغاء العقد المعاكس بمجرد تفعيل احدهما
يعنى مثلا

كود PHP:

  if ( MyOrdersTotal(Magicnumber)==0)
{
    DeletePendingOrders(Magicnumber);
  } 


الاكسيرت فى المرفقات ارجو من اخى وجدى الاطلاع عليه وتصحيحه

كود الاكسبيرت

كود PHP:

//+------------------------------------------------------------------+
//|                                  ahmed ibrahim-mohamed maamo.mq4 |
//|                                   Copyright © 2009,Ahmed Ibrahim |
//|                                        http://www.metaquotes.net |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2009,Ahmed Ibrahim"
#property link      "http://www.metaquotes.net"

extern int     Step=120;
extern int     Takeprofit=100;
extern int     Stoploss=100;
extern double  Lots=1;
 int     MagicNumber = 5000;;

//+------------------------------------------------------------------+
//| expert initialization function                                   |
//+------------------------------------------------------------------+
int init()
  {
//----
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert deinitialization function                                 |
//+------------------------------------------------------------------+
int deinit()
  {
//----
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert start function                                            |
//+------------------------------------------------------------------+
int start()
{
  if(Hour()==0 && Minute()<5 && MyOrdersTotal(Magicnumber)>0)
  {
    DeletePendingOrders(Magicnumber);
    CloseOrders(Magicnumber);
  }
  if(Hour()==0 && Minute()>5 && MyOrdersTotal(Magicnumber)==0)
  {
    double Dayopen=iOpen(Symbol(),PERIOD_H1,0);
    double BuyPrice=Dayopen+Step*Point;
    double BuyTP=BuyPrice+Takeprofit*Point;
    double BuySL=BuyPrice-Stoploss*Point;
    
    double SellPrice=Dayopen-Step*Point;
    double SellTP=SellPrice-Takeprofit*Point;
    double SellSL=SellPrice+Stoploss*Point;
    
    OrderSend(Symbol(),OP_BUYSTOP,Lots,BuyPrice,3,BuySL,BuyTP,"",Magicnumber,0,Green);
    OrderSend(Symbol(),OP_SELLSTOP,Lots,SellPrice,3,SellSL,SellTP,"",Magicnumber,0,Green);
  }
  return(0);
}
int MyOrdersTotal(int Magic)
{
  int c=0;
  int total  = OrdersTotal();
  
  for (int cnt = 0 ; cnt < total ; cnt++)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol())
    {
      c++;
    }
  }
  return(c);
}
int DeletePendingOrders(int Magic)
{
  int total  = OrdersTotal()-1;
  
  for (int cnt = total ; cnt > 0 ; cnt--)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol() && (OrderType()!=OP_BUY || OrderType()!=OP_SELL))
    {
      OrderDelete(OrderTicket());
    }
  }
  return(0);
}
int CloseOrders(int Magic)
{
  int total  = OrdersTotal()-1;
  
  for (int cnt = total ; cnt > 0 ; cnt--)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol())
    {
      if (OrderType()==OP_BUY)
      {
        OrderClose(OrderTicket(),OrderLots(),Bid,3);
      }
      
      if (OrderType()==OP_SELL)
      {
        OrderClose(OrderTicket(),OrderLots(),Ask,3);
      }
    }
  }
  return(0);
} 


[مهندس وجدي]

أخواني الكريم

الخطوة الاولى

راجعوا الملاحظات الموجودة في هذه الصورة



ثم ارفقوا الاكسبيرت بعد تعديل الاخطاء السابقة لننتقل للملاحظات الاخرى

تحياتي

[التائب اليك]

مشكور على تثبيت الموضوع وان شاء الله حيستفيد منه ناس كتير

بس
الصوره عندى مش ظاهره يا بشمهندس

[مهندس وجدي]

المشاركة الأصلية كتبت بواسطة التائب اليك

مشكور على تثبيت الموضوع وان شاء الله حيستفيد منه ناس كتير

بس
الصوره عندى مش ظاهره يا بشمهندس

أخواني الكريم

السبب في عدم ظهور الصور هو متصفح Internet Explorer لذلك الأفضل أن تستخدموا متصفح فايرفوكس

وعلى العموم

الصورة على هذا الرابط

4shared.com - photo sharing - download image 290609.jpg

ولكن أرجو استخدام متصفح فايرفوكس حتى يتم اصلاح مشكلة الصور بالنسبة لمتصفح Internet Explorer من قبل الدعم الفني

تحياتي

[التائب اليك]

ياريت يا بشمهندس تشوفلنا حل فى الصوره اللى فيها الملحوظات لانها مش ظاهره عنى

وجزاك الله كل خير

[مهندس وجدي]

المشاركة الأصلية كتبت بواسطة التائب اليك

ياريت يا بشمهندس تشوفلنا حل فى الصوره اللى فيها الملحوظات لانها مش ظاهره عنى

وجزاك الله كل خير

أخي الكريم

ليس هناك مشاكل في رؤية الصور عند استخدام متصفح فايرفوكس

وبالنسبة لمتصفح Internet Explore فهذا اقتباس للدعم الفني وبه الحل ان شاء الله

المشاركة الأصلية كتبت بواسطة الدعم الفني للموقع 2

جرب عمل الآتي

1- مسح الملفات المؤقتة
من قائمة Tools اضغط Delete Browsing History
هيطلع صندوق حواري اضغط Delete Files
ثم اضغط ok
اقفل ااكسبلورر وافتحه مرة اخرى

2- تأكد من تفعيل اختيار ال show picture
من قائمة Tools اضغط internet options
ُم اضغط على advanced tab
ثم تحقق من ان التشيك بوكس Show Pictures مفعل وذلك تحت اختيارات multimedia
ثم اضغط ok

3- تأكد من ان الجافا والاكتيف اكس والكوكيز مفعلين داخل متصفحك وذلك عن طريق
من قائمة tools اضغط internet options
اضغط security tab ثم اضغط defult level اذا كان الزرار متاح

4- تأكد من ان قائمة page واشر على Encoding وتأكد من ان ال Auto-Select مفعل اذل لم يكن مفعل قم بالضغط عليه حتى تظهر علامة الصح

5- تاكد من ان اختيار اللغة صحيح حيث انه من الممكن ان تكون المشكلة في اسم الصورة او العربي مثلا وذلك عن طريق
قائمة page ثم encoding واختار اللغة المناسبة للموقع الذي تتصفحه يعني لو عربي اختار عربي لو انجليزي اختار انجليزي

6- من الممكن ان الانتي فيرس الذي تستخدمه او برنامج ال firewall ممكن يكون عامل بلوك للصور مثلا قم بتعطيل الانتي فيرس مؤقتا وجرب مرة اخرى

ارجو تجربة الخطوات السابقة حيث انني بالفعل لم اجد حتى الان مشكلة بالمنتدى تتسبب بعدم ظهور الصور خصوصا بعد ان افاد الاستاذ محسن والمهندس حاتم بان الصور تظهر معهم بشكل طبيعي وانا كمان الصور بتظهر معايا بشكل طبيعي

شكرا لك

يمكنك مشاهدة الصورة باستخدام متصفح فايرفوكس

أو

على متصفح Internet Explore بعد عمل الخطوات السابقة (الاقتباس)

أو

مشاهدة الصورة على هذا الرابط

4shared.com - photo sharing - download image 290609.jpg

أو

من مرفقات هذه المشاركة

تحياتي

[التائب اليك]

كده صح يا بشمهندس
بس برده الاسم ظاهر بلون فضى

على العموم فى انتظار ملاحظاتك
وجزاك الله كل خير

[مهندس وجدي]

المشاركة الأصلية كتبت بواسطة التائب اليك

كده صح يا بشمهندس
بس برده الاسم ظاهر بلون فضى

على العموم فى انتظار ملاحظاتك
وجزاك الله كل خير

أخي الكريم

اللون الفضي معناه ان صيغة mq4 من الاكسبيرت غير موجودة
أو
صيغة mq4 موجودة ولكن هناك أخطاء برمجية
(وهذا ما يحصل معك)

لذلك يجب عليك دائماً ان تضغط على F5 أو Compile قبل تجريب الاكسبيرت على الشارت ويجب ألا يكون هناك اي خطأ برمجي


درس اليوم

الخطأ موضح في الصورة المرفقة

قم بتصحيح الخطأ ثم اضغط على F5 أو Compile ثم احفظ الاكسبيرت بإسم جديد ثم ارفقه هنا لننتقل للخطوة الجديدة
وتأكد ان الاكسبيرت اصبح ملون وحاول ان تعمل باك تيست واخبرنا بالملاحظات

تحياتي

[التائب اليك]

جزاك الله خيرا يا وجدى
الاكسبيرت اشتغل تمام
من الباك تست
قمت بتغيير

1- ال FIRSTLOTS=1 لتصبح 0.01
2- حاجه تانيه

كود PHP:

int DeletePendingOrders(int Magic)
{
  int total  = OrdersTotal()-1;
  
  for (int cnt = total ; cnt > 0 ; cnt--)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol() && (OrderType()!=OP_BUY || OrderType()!=OP_SELL))
    {
      OrderDelete(OrderTicket());
    }
  }
  return(0);
} 


ليصبح

كود PHP:

for (int cnt = total ; cnt > 0 ; cnt--)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol() && (OrderType()!=OP_BUYSTOP || OrderType()!=OP_SELLSTOP)) 


انا جيت عملت باك تست يوم 1/7/2009 لقيت انه لم يغلق الصفقه امفتوحه وسابها لحد تانى يوم بس عمل دليت الصفقه المعلقه.

يوم تانى تم ضرب الاستوب لوس فى نفس اليوم لكن مدلتش الصفقه المعلقه

اتجنيت انا خلاص

[مهندس وجدي]

المشاركة الأصلية كتبت بواسطة التائب اليك

جزاك الله خيرا يا وجدى
الاكسبيرت اشتغل تمام
من الباك تست
قمت بتغيير

1- ال FIRSTLOTS=1 لتصبح 0.01
2- حاجه تانيه

كود PHP:

int DeletePendingOrders(int Magic)
{
  int total  = OrdersTotal()-1;
  
  for (int cnt = total ; cnt > 0 ; cnt--)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol() && (OrderType()!=OP_BUY || OrderType()!=OP_SELL))
    {
      OrderDelete(OrderTicket());
    }
  }
  return(0);
} 


ليصبح

كود PHP:

for (int cnt = total ; cnt > 0 ; cnt--)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol() && (OrderType()!=OP_BUYSTOP || OrderType()!=OP_SELLSTOP)) 


انا جيت عملت باك تست يوم 1/7/2009 لقيت انه لم يغلق الصفقه امفتوحه وسابها لحد تانى يوم بس عمل دليت الصفقه المعلقه.

يوم تانى تم ضرب الاستوب لوس فى نفس اليوم لكن مدلتش الصفقه المعلقه

اتجنيت انا خلاص

نأتي الآن للأخطاء المنطقية

قم بحذف هذه الأكواد من الاكسبيرت
(تجدها في اسفل الكود)

كود PHP:

int MyOrdersTotal(int Magic)
{
  int c=0;
  int total  = OrdersTotal();
  
  for (int cnt = 0 ; cnt < total ; cnt++)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol())
    {
      c++;
    }
  }
  return(c);
}
int DeletePendingOrders(int Magic)
{
  int total  = OrdersTotal()-1;
  
  for (int cnt = total ; cnt > 0 ; cnt--)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol() && (OrderType()!=OP_BUYSTOP || OrderType()!=OP_SELLSTOP))
    {
      OrderDelete(OrderTicket());
    }
  }
  return(0);
}
int CloseOrders(int Magic)
{
  int total  = OrdersTotal()-1;
  
  for (int cnt = total ; cnt > 0 ; cnt--)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol())
    {
      if (OrderType()==OP_BUY)
      {
        OrderClose(OrderTicket(),OrderLots(),Bid,3);
      }
      
      if (OrderType()==OP_SELL)
      {
        OrderClose(OrderTicket(),OrderLots(),Ask,3);
      }
    }
  }
  return(0);
} 


واستبدلها بالاكواد التالية
(اسفل الكود الأصلي)

كود PHP:

// وظيفة لحساب عدد الصفقات الحالية
int MyRealOrdersTotal(int Magic)
{
  int c=0;
  int total  = OrdersTotal();
  t1=-1;
  t2=-1;
 
  for (int cnt = 0 ; cnt < total ; cnt++)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol() && (OrderType()==OP_BUY || OrderType()==OP_SELL))
    {
      if (t1==-1)
      {
        t1=OrderTicket();
      }
      else
      {
        if (t2==-1)
        {
          t2=OrderTicket();
        }
      }
      c++;
    }
  }
  return(c);
}

// وظيفة لحساب عدد الصفقات المعلقة فقط
int MyPendingOrdersTotal(int Magic)
{
  int c=0;
  int total  = OrdersTotal();  
 
  for (int cnt = 0 ; cnt < total ; cnt++)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol() && (OrderType()==OP_BUYSTOP || OrderType()==OP_SELLSTOP || OrderType()==OP_BUYLIMIT || OrderType()==OP_SELLLIMIT))
    {
      c++;
    }
  }
  return(c);
}

// وظيفة لحذف الصفقات المعلقة
int DeletePendingOrders(int Magic)
{
int total  = OrdersTotal();
 
for (int cnt = total - 1; cnt >= 0; cnt--)
{
 OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
 if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol() && (OrderType()==OP_BUYSTOP || OrderType()==OP_SELLSTOP || OrderType()==OP_BUYLIMIT || OrderType()==OP_SELLLIMIT))
 {
   OrderDelete(OrderTicket());
 }
}
return(0);
}

// اغلاق جميع الصفقات المفتوحة
//+------------------------------------------------------------------+
int CloseOrders(int Magic)
{
  int total  = OrdersTotal();
  
  for (int cnt = 0 ; cnt < total ; cnt++)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol())
    {
      if (OrderType()==OP_BUY)
      {
        if(OrderClose(OrderTicket(),OrderLots(),Bid,3)==false)
         {
           RefreshRates();
         }
         else
         {
           cnt=0;
           total=OrdersTotal();
         }
      }
      
      if (OrderType()==OP_SELL)
      {
        if(OrderClose(OrderTicket(),OrderLots(),Ask,3)==false)
         {
           RefreshRates();
         }
         else
         {
           cnt=0;
           total=OrdersTotal();
         }
      }
    }
  }
  return(0);
} 


ثم ضع هذا السطر في أعلى الكود

كود PHP:

int    t1,t2; 


تحت هذا السطر

كود PHP:

extern int     MagicNumber = 5000; 


ثم استبدل هذا السطر

كود PHP:

  if(Hour()==0 && Minute()<5 && MyOrdersTotal(MagicNumber)>0) 


بهذا السطر

كود PHP:

  if(Hour()==0 && Minute()<5 && (MyRealOrdersTotal(MagicNumber) + MyPendingOrdersTotal(MagicNumber))>0 ) 


واستبدل هذا السطر

كود PHP:

  if(Hour()==0 && Minute()>5 && MyOrdersTotal(MagicNumber)==0) 


بهذا السطر

كود PHP:

  if(Hour()==0 && Minute()>5 && MyPendingOrdersTotal(MagicNumber)<2) 


ثم قم بالضغط على F5 أو Compile و احفظ الاكسبيرت بإسم جديد وارفقه هنا لننتقل للخطوة الجديدة

وقم بعمل باك تيست واخبرنا بالملاحظات

يجب ان يكون الكود النهائي مثل هذا الكود

كود PHP:

//+------------------------------------------------------------------+
//|                               ahmed ibrahim-mahamed maamo v1.mq4 |
//|                                   Copyright © 2009,Ahmed Ibrahim |
//|                                        http://www.metaquotes.net |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2009,Ahmed Ibrahim"
#property link      "http://www.metaquotes.net"

//+------------------------------------------------------------------
extern int     Step=120;
extern int     Takeprofit=100;
extern int     Stoploss=100;
extern double  Lots=0.01;
extern int     MagicNumber = 5000;
int    t1,t2;

//+------------------------------------------------------------------+
//| expert initialization function                                   |
//+------------------------------------------------------------------+
int init()
  {
//----
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert deinitialization function                                 |
//+------------------------------------------------------------------+
int deinit()
  {
//----
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert start function                                            |
//+------------------------------------------------------------------+
int start()
{
  if(Hour()==0 && Minute()<5 && (MyRealOrdersTotal(MagicNumber) + MyPendingOrdersTotal(MagicNumber))>0 )
  {
    CloseOrders(MagicNumber);
    DeletePendingOrders(MagicNumber); 
 
  }
  if(Hour()==0 && Minute()>5 && MyPendingOrdersTotal(MagicNumber)<2)
  {
    double Dayopen=iOpen(Symbol(),PERIOD_H1,0);
    double BuyPrice=Dayopen+Step*Point;
    double BuyTP=BuyPrice+Takeprofit*Point;
    double BuySL=BuyPrice-Stoploss*Point;
    
    double SellPrice=Dayopen-Step*Point;
    double SellTP=SellPrice-Takeprofit*Point;
    double SellSL=SellPrice+Stoploss*Point;
    
    OrderSend(Symbol(),OP_BUYSTOP,Lots,BuyPrice,3,BuySL,BuyTP,"",MagicNumber,0,Green);
    OrderSend(Symbol(),OP_SELLSTOP,Lots,SellPrice,3,SellSL,SellTP,"",MagicNumber,0,Green);
  }
  return(0);
}

// وظيفة لحساب عدد الصفقات الحالية
int MyRealOrdersTotal(int Magic)
{
  int c=0;
  int total  = OrdersTotal();
  t1=-1;
  t2=-1;
 
  for (int cnt = 0 ; cnt < total ; cnt++)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol() && (OrderType()==OP_BUY || OrderType()==OP_SELL))
    {
      if (t1==-1)
      {
        t1=OrderTicket();
      }
      else
      {
        if (t2==-1)
        {
          t2=OrderTicket();
        }
      }
      c++;
    }
  }
  return(c);
}

// وظيفة لحساب عدد الصفقات المعلقة فقط
int MyPendingOrdersTotal(int Magic)
{
  int c=0;
  int total  = OrdersTotal();  
 
  for (int cnt = 0 ; cnt < total ; cnt++)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol() && (OrderType()==OP_BUYSTOP || OrderType()==OP_SELLSTOP || OrderType()==OP_BUYLIMIT || OrderType()==OP_SELLLIMIT))
    {
      c++;
    }
  }
  return(c);
}

// وظيفة لحذف الصفقات المعلقة
int DeletePendingOrders(int Magic)
{
int total  = OrdersTotal();
 
for (int cnt = total - 1; cnt >= 0; cnt--)
{
 OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
 if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol() && (OrderType()==OP_BUYSTOP || OrderType()==OP_SELLSTOP || OrderType()==OP_BUYLIMIT || OrderType()==OP_SELLLIMIT))
 {
   OrderDelete(OrderTicket());
 }
}
return(0);
}

// اغلاق جميع الصفقات المفتوحة
//+------------------------------------------------------------------+
int CloseOrders(int Magic)
{
  int total  = OrdersTotal();
  
  for (int cnt = 0 ; cnt < total ; cnt++)
  {
    OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
    if (OrderMagicNumber() == Magic && OrderSymbol()==Symbol())
    {
      if (OrderType()==OP_BUY)
      {
        if(OrderClose(OrderTicket(),OrderLots(),Bid,3)==false)
         {
           RefreshRates();
         }
         else
         {
           cnt=0;
           total=OrdersTotal();
         }
      }
      
      if (OrderType()==OP_SELL)
      {
        if(OrderClose(OrderTicket(),OrderLots(),Ask,3)==false)
         {
           RefreshRates();
         }
         else
         {
           cnt=0;
           total=OrdersTotal();
         }
      }
    }
  }
  return(0);
} 


اكتب الملاحظات حتى ننتقل للخطوة القادمة

تحياتي